path: root/vimrc

" General {{{1
set nocompatible
let g:use_dvorak = 1
let g:leave_my_cursor_position_alone = ''
let PHP_vintage_case_default_indent = 1
let c_no_comment_fold = 1
set fileformats=unix,dos,mac
set spelllang=en_us
set switchbuf=useopen

" Colors and Syntax {{{1
set background=dark
colorscheme zlg
if has('syntax') && !exists('g:syntax_on')
	syntax enable
endif

" Plugin-Specific {{{1
call pathogen#infect('bundle/{}')
Helptags

" Formatting {{{1
set formatprg=par-format\ w80
set printoptions=paper:letter,top:0.5in,left:0.5in,right:0.5in,bottom:0.5in,syntax:n,header:0
set tabstop=4
set softtabstop=4
set shiftwidth=4
set noexpandtab
set formatoptions=tcqn

" Usability {{{1
set whichwrap=<,>,[,],h,l
set scrolloff=2
set backspace=indent,eol,start
set ttimeout
set ttimeoutlen=50
set timeoutlen=3000
set incsearch
set number
set numberwidth=5
set hidden
set mouse=n

" Interface {{{1
set display+=lastline
" I changed my mind... a toggle is best
set nolist
"set listchars=tab:⇥\ ,trail:␣,extends:⇉,precedes:⇇,nbsp:⚭
if &termencoding ==# 'utf-8' || &encoding ==# 'utf-8'
	let &listchars = "tab:\u21e5 ,extends:\u21c9,precedes:\u21c7,nbsp:\u26ad"
else
	set listchars=tab:>\ ,extends:>,precedes:<,nbsp:+
endif
set splitright
set splitbelow
set laststatus=2
" Example: (1) .vimrc [vim][+] 48,22 123L 0x20
set statusline=(%n)\ %f\ %y%r%m\ %l,%v\ %LL\ 0x%B
set fillchars=fold:\ ,vert:\|
set wrap
set linebreak

" Anti-Annoyance {{{1
set nostartofline
set novisualbell
set noautoindent

" Folding {{{1
set foldmethod=expr
set foldtext=MyFoldText()

function! MyFoldText()
	let indent = repeat('	', indent(v:foldstart))
	let line = substitute(getline(v:foldstart), '\v^\s+', '', '')
	let folded_lines = v:foldend - v:foldstart
	return indent . line . ' (' . folded_lines . 'L)'
endfunction


" Autocommands {{{1
if has("autocmd")
	filetype plugin indent on
	autocmd BufNewFile,BufRead /media/sd/Games/*.[0123456789].txt setfiletype sctxt
	autocmd BufNewFile,BufRead *.txt setfiletype text
	" All Markdown and TXT files need to be hard wrapped to 80 characters.
	autocmd FileType text,markdown setlocal nonumber tabstop=4 softtabstop=4 shiftwidth=4 expandtab formatoptions=tcqwn textwidth=80 nolist colorcolumn=81
	autocmd FileType python setlocal expandtab
	autocmd BufNewFile,BufRead *.ledger setlocal nonumber iskeyword+=: filetype=ledger
	autocmd FileType help setlocal colorcolumn=0
	autocmd FileType vim setlocal keywordprg=:help
	autocmd FileType c setlocal foldmethod=syntax
	" Needed for game guides on the SuperCard DSTWO; this is also true of
	" homebrew apps that use monospace fonts at normal scale. The DSTWO throws
	" up on linebreaks if it's not DOS, iso8859-1 text. The limit is set to
	" allow for a character or two that might be wider than an M or W.
	autocmd FileType sctxt setlocal enc=latin1 ff=dos tw=30 cc=31 fo=tcqwn nolist et ts=4 sts=4 sw=4
endif

" Key Bindings {{{1
nnoremap <leader>i :call <SID>SynStack()<CR>
nnoremap <leader>l :set list!<CR>
nnoremap <leader>n :set number!<CR>
nnoremap <leader>t :setfiletype text<CR>
nnoremap <leader>s :set spell!<CR>
nnoremap <leader>c :call <SID>CountCodeLines()<CR>
nnoremap <leader>d :call <SID>InsertDOW()<CR>
nnoremap <leader>D "=strftime("%Y-%m-%d %H:%M", localtime())<CR>p
nnoremap <Space> za
nnoremap <silent> <F5> :call <SID>StripTrailingWhitespaces()<CR>

" Thanks to /u/spupy for these short and sweet mappings that replace the
" simpler functions of tpope's surround.vim plugin. Each of these will
" surround the current (or last) visual selection with the specified 
" character.
noremap <Leader>w" <ESC>`>a"<ESC>`<i"<ESC>
noremap <Leader>w' <ESC>`>a'<ESC>`<i'<ESC>
noremap <Leader>w( <ESC>`>a)<ESC>`<i(<ESC>
noremap <Leader>w[ <ESC>`>a]<ESC>`<i[<ESC>
noremap <Leader>w{ <ESC>`>a}<ESC>`<i{<ESC>
noremap <Leader>w< <ESC>`>a><ESC>`<i<<ESC>
noremap <Leader>w` <ESC>`>a`<ESC>`<i`<ESC>


" Dvorak Hackery {{{1
if (exists("g:use_dvorak") && g:use_dvorak == 1)
	" I use a Dvorak keyboard, so standard vim movement keys are a hassle.
	" Since mnemonics are helpful all around, I need a mapping that gives me
	" pain-free file navigation without screwing up mnemonics (too much).
	"
	" Thus:
	" (D)elete is now (K)ill: d2w == k2w "kill 2 words"
	" Un(T)il is now (J)ump-To: dt( == kj( "kill, jump-to paren"
	" (N)ext is now (L)eap: cn == cl "change up to leap point"

	" Standard movement, which is the true focus of this hack.
	" Mnemonics are awesome, so let's preserve as much as possible.
	noremap d h
	noremap h j
	noremap t k
	noremap n l
	noremap D H
	noremap H J
	noremap T K
	noremap N L

	noremap gh gj
	noremap gt gk

	" I work with tabs every now and then. No, I don't have a mnemonic, so
	" stfu.
	noremap gj gt
	noremap gJ gT

	" Window movement, equally important
	noremap <C-w>d <C-w>h
	noremap <C-w>h <C-w>j
	noremap <C-w>t <C-w>k
	noremap <C-w>n <C-w>l

	nnoremap <C-w><C-d> <C-w><C-h>
	nnoremap <C-w><C-h> <C-w><C-j>
	nnoremap <C-w><C-t> <C-w><C-k>
	nnoremap <C-w><C-n> <C-w><C-l>

	nnoremap <C-d> <C-w>h
	nnoremap <C-h> <C-w>j
	nnoremap <C-t> <C-w>k
	nnoremap <C-n> <C-w>l

	" Account for tag jumping
	nnoremap <C-j> <C-t>

	" Remappings for the D key
	noremap k d
	noremap K D

	" Remappings for the T key
	noremap j t
	noremap J T

	" Remapping for the L key
	noremap l n
	noremap L N

	" General purpose help; the originals remain for convenience
	noremap - 0
	noremap _ $

	" Fold-related keybindings
	noremap zh zj
	noremap zt zk

endif

" Functions {{{1
" Credit to Drew Neil of vimcasts.org
function! <SID>StripTrailingWhitespaces() " {{{2
	" Save last search and cursor position
	let _s=@/
	let l = line(".")
	let c = col(".")
	" Do the business:
	%s/\s\+$//e
	" Restore previous search history and cursor position
	let @/=_s
	call cursor(l, c)
endfunction

" Credit to Drew Neil of vimcasts.org
function! <SID>SynStack() " {{{2
	if !exists("*synstack")
		return
	endif
	echo map(synstack(line('.'), col('.')), 'synIDattr(v:val, "name")')
endfunction

function! <SID>CountCodeLines() " {{{2
	let code_count = 0
	for line in getbufline("%", 1, "$")
		if (len(line) > 0 && match(line, '\S\+') > -1)
			if (s:IsCommentLine(line) == 1)
				continue
			endif
			let code_count += 1
		endif
	endfor
	echo code_count . ' lines of code.'
endfunction

function! s:IsCommentLine(line) " {{{2
	let l:comtypes = []
	let l:comlist = split(&comments, ',')
	for i in comlist
		let l:type = split(i, ':')
		if len(type) > 1
			let l:opt = type[1]
		else
			let l:opt = type[0]
		endif
		call add(comtypes, opt)
	endfor
	let i = 0
	while i < len(comtypes)
		if match(a:line, '^\s*' . escape(comtypes[i], '/*')) > -1
			return 1
		endif
		let i += 1
	endwhile
	return 0
endfunction

function! <SID>InsertDOW() " {{{2
	" Let's backup a random register
	let tmpx = @x
	let @x = system("date +\"%a \" -d" . strftime("%Y") . "-" . substitute(expand("<cWORD>"), ":", "", ""))
	normal "xP
	" Join, since it apparently is on a line instead of just a string
	j 1
	" Return the value in the x register
	let @x = tmpx
endfunction
" vim: foldmethod=marker